One-dimensional fundamental solution

g[x_,t_,k_]=Exp[-x^2/4/k/t]/Sqrt[4 Pi k t]

DensityPlot[g[x,1,1],{x,-5,5},{y,0.05,0.5},
PlotRange->All,
ColorFunction->(GrayLevel[1-#]&),
ColorFunctionScaling->False,
PlotPoints->50,
AspectRatio->Automatic,
Frame->None,
Axes->{True,False}]

GraphicsColumn[{
Plot[g[x,1,1],{x,-5,5},
PlotRange->{0,1},
ImageSize->Large,
AspectRatio->1/4,
ImagePadding->Automatic],
DensityPlot[g[x,1,1],{x,-5,5},{y,0.05,0.5},
PlotRange->All,
ColorFunction->(GrayLevel[1-#]&),
ColorFunctionScaling->False,
PlotPoints->50,
AspectRatio->Automatic,
Frame->None,
Axes->{True,False},
ImagePadding->{{35,35},{10,0}}]}]

Animate[
GraphicsColumn[{
Plot[g[x,t,1],{x,-5,5},PlotRange->{0,1},ImageSize->Large,AspectRatio->1/4],
DensityPlot[g[x,t,1],{x,-5,5},{y,0.05,0.5},
PlotRange->All,
ColorFunction->(GrayLevel[1-#]&),
ColorFunctionScaling->False,
PlotPoints->50,
AspectRatio->Automatic,
Frame->None,
Axes->{True,False},
ImagePadding->{{35,35},{10,0}}]}],
{t,0.001,1},
AnimationRunning->False,AnimationRate->0.1]

Two-dimensional fundamental solution

g[x_,y_,t_,k_]=Exp[-(x^2+y^2)/4/k/t]/4/Pi/k/t

Another way to visualize the two-dimensional fundamental solution is with a density plot generated using the command DensityPlot:

DensityPlot[g[x,y,0.1,1],{x,-5,5},{y,-5,5},
PlotRange->All,
ColorFunction->(GrayLevel[1-#]&),
ColorFunctionScaling->False,
PlotPoints->150]

We can animate:

Animate[DensityPlot[g[x,y,t,1],{x,-5,5},{y,-5,5},
PlotRange->All,
ColorFunction->(GrayLevel[1-#]&),
ColorFunctionScaling->False,
PlotPoints->50],
{t,0.001,0.5},
AnimationRunning->False]

In the animation above, the resolution is a bit low in order to allow Mathematica to keep up in generating frames.  For better resolution (with PlotPoints->150),  we generate the frames in advance and then use ListAnimate:

frames1=Table[DensityPlot[g[x,y,t,1],{x,-5,5},{y,-5,5},
PlotRange->All,
ColorFunction->(GrayLevel[1-#]&),
ColorFunctionScaling->False,
PlotPoints->150],
{t,0.001,0.5,0.01}];

ListAnimate[frames1,AnimationRunning->False]